!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
! IDENT      This MIDAS programme file is called literature.prg.
!            MIDAS:   Munich Image Data Analysis System.
!            Version: August 19, 2008.
! PURPOSE    This programme analyses scientific publication data.
! AUTHOR     Marc Fluks.
! COMMENTS   > You need the ESO-MIDAS and Unix/Linux distributions.
!              Download ESO-MIDAS: http://www.eso.org/projects/esomidas/midas.html
!              Download Redhat Linux: http://www.redhat.com/
!              This programme also runs on DEC/VAX/VMS MIDAS (rewrite Unix commands).
!            > This programme runs for Year>1995.0 only.
!            > This programme runs for #rows input file>60 only.
!            > The input and output files can be obtained from:
!              http://www.me-net.combidom.com/library/literature.htm
!            > The input files.
!                 literature.dat   (ascii, the data file)
!                 literature.prg   (ascii, the programme file)
!              Format of literature.dat:
!                 Empty entries must be indicated by an *.
!                 1st  column: month.
!                 2nd  column: day of the month.
!                 3rd  column: year.
!                 4th  column: day number (empty).
!                 5th  column: number of papers/month.
!                 6th  column: number of CFS/ME papers/month.
!                 7th  column: number of FMS papers/month.
!                 8th  column: number of papers/5years.
!                 9th  column: number of CFS/ME papers/5years.
!                 10th column: number of FMS papers/5years.
!                 11th column: progress of papers/5years.
!                 12th column: progress of CFS/ME papers/5years.
!                 13th column: progress of FMS papers/5years.
!              +  Columns 1-3 correspond to mm/dd/yyyy.
!              +  Column 4 is empty (indicated by an *).
!              +  Columns 5-7 correspond to the literature update.
!              +  This months entries for Columns 8-13 are taken from this
!                 months output file. Run the programme with empty entries
!                 (indicated by an *) in the last row and then include the 
!                 results for future reference. You don't need to run the
!                 programme again.
!            > Run the programme with the command line,
!                 inmidas
!              followed by the MIDAS command line,
!                 @@ literature
!            > The output files.
!                Graphic files:
!                 literature1.jpg
!                 literature2.jpg
!                 literature3.jpg
!                Text files:
!                 literature.tbl   (binary)
!                 literature.txt   (ascii version of literature.tbl)
!                Format of text files:
!                 1st  column: sequence number (1-60; the past 60 months).
!                 2nd  column: year.
!                 3rd  column: number of papers/day.
!                 4th  column: number of CFS/ME papers/day.
!                 5th  column: number of FMS papers/day.
!                 6th  column: number of papers/5years.
!                 7th  column: number of CFS/ME papers/5years.
!                 8th  column: number of FMS papers/5years.
!                 9th  column: progress of papers/5years.
!                 10th column: progress of CFS/ME papers/5years.
!                 11th column: progress of FMS papers/5years.
!                 descriptors: additional info (literature.tbl only).
!-----------------------------------------------------------------------
  ECHO/FULL
  SET/FORMAT E18.12

! Create literature.tbl.
  CREA/TAB literature 13 ? literature
  NAME/COL literature #1 :MONTH    F2.0 "month"
  NAME/COL literature #2 :DAY      F6.1 "day"
  NAME/COL literature #3 :Year     F8.3 ""
  NAME/COL literature #4 :DAYNR    F6.1 "day"         ! Codes:
  NAME/COL literature #5 :QQQQ0001 F4.2 "number/day"  ! 0001=ALL
  NAME/COL literature #6 :QQQQ0002 F4.2 "number/day"  ! 0002=CFS
  NAME/COL literature #7 :QQQQ0003 F4.2 "number/day"  ! 0003=FMS
  NAME/COL literature #8 :SUMALL   F4.0 "number/5years"
  NAME/COL literature #9 :SUMCFS   F4.0 "number/5years"
  NAME/COL literature #10 :SUMFMS  F4.0 "number/5years"
  NAME/COL literature #11 :PROALL  F3.0 "%/5years"
  NAME/COL literature #12 :PROCFS  F3.0 "%/5years"
  NAME/COL literature #13 :PROFMS  F3.0 "%/5years"
  COMP/TAB literature :PROALL = 100.0*:PROALL
  COMP/TAB literature :PROCFS = 100.0*:PROCFS
  COMP/TAB literature :PROFMS = 100.0*:PROFMS

! Compute day number :DAYNR (Day #1 being 1/1/2001).
  COPY/TAB literature midtemp
  COMP/TAB midtemp :M = (:MONTH+1)+6.*(1.-ABS(:MONTH-2.5)/(:MONTH-2.5))
  COMP/TAB midtemp :M = 30.6*:M
  COMP/TAB midtemp :DAYNR = ABS(INT(:M)-:M)/(INT(:M)-:M+1.E-18)
  COMP/TAB midtemp :DAYNR = :DAYNR*((:DAYNR+1.0)/2.0)
  COMP/TAB midtemp :M = INT(:M-0.5*:DAYNR)
  COMP/TAB midtemp :Y = :Year+(ABS(:MONTH-2.5)/(:MONTH-2.5)-1.)/2.
  COMP/TAB midtemp :Y = 365.25*:Y
  COMP/TAB midtemp :DAYNR = ABS(INT(:Y)-:Y)/(INT(:Y)-:Y+1.E-18)
  COMP/TAB midtemp :DAYNR = :DAYNR*((:DAYNR+1.0)/2.0)
  COMP/TAB midtemp :Y = INT(:Y-0.5*:DAYNR)
  COMP/TAB midtemp :DAYNR = ((:DAY-730928.0)+(:M+:Y))
  COPY/TT midtemp  :DAYNR literature :DAYNR

! Compute day number bin :DAYS and center :DAYNR to its proper position.
  STAT/TAB midtemp :DAYNR
  WRITE/KEY QQP2/C/1/40 'OUTPUTI(2)'
  WRITE/KEY QQP3/R/1/1 1
  COMP/KEY QQP3 = 'QQP3'-0.5
  COMP/TAB midtemp :ROW = SEQ
  COPY/KT QQP3 midtemp :ROW @'QQP2'
  SORT/TAB midtemp :ROW
  DEL/COL midtemp :ROW
  COMP/TAB midtemp :QQ = LOG10(SEQ-1)+1
  COMP/TAB midtemp :DAYS = :DAYNR*(:QQ/:QQ)
  COPY/TT midtemp  :DAYS literature :DAYS
  COMP/TAB literature :QQ = :DAYS
  COMP/TAB literature :DAYS = :DAYNR-:DAYS
  COMP/TAB literature :DAYNR = .5*(:DAYNR+:QQ)
  DEL/COL literature :QQ

! Update literature.tbl.
  COMP/TAB literature :I0001 = :QQQQ0001
  COMP/TAB literature :I0002 = :QQQQ0002
  COMP/TAB literature :I0003 = :QQQQ0003
! Compute the number of papers/day.
  COMP/TAB literature :QQQQ0001 = :QQQQ0001/:DAYS
  COMP/TAB literature :QQQQ0002 = :QQQQ0002/:DAYS
  COMP/TAB literature :QQQQ0003 = :QQQQ0003/:DAYS
  COMP/TAB literature :Year = 2001+(:DAYNR-1)/365.25
  DEL/COL literature :DAY
  DEL/COL literature :DAYS
  DEL/COL literature :DAYNR
  DEL/COL literature :MONTH
! Delete first row.
  SORT/TAB literature :Year
  STAT/TAB literature :Year
  WRITE/DESCR literature.tbl TBLCONTR/I/4/4 'OUTPUTI(2)'
! Select last 60 rows only, corresponding to 5 years.
  COMP/TAB literature :ROW = -1.*SEQ
  SORT/TAB literature :ROW
  WRITE/DESCR literature.tbl TBLCONTR/I/4/4 60
  DEL/COL literature :ROW
  SORT/TAB literature :Year

! Create the graph, define format.
  CREATE/GRAPH
  STAT/TAB literature :Year
  WRITE/KEY XYEAR/R/1/1 'OUTPUTR(2)'
  WRITE/KEY XUP/D/1/1 1995.0
  WRITE/KEY LOOP/I/1/1 0
  DO LOOP = 1 300 1
  IF XUP .LE. XYEAR THEN
  COMP/KEY XUP = XUP+.083333333333
  ELSE
  ENDIF
  ENDDO
  WRITE/KEY XLOW/D/1/1 'XUP'
  COMP/KEY XLOW = 'XLOW'-5.
! Set X-axis.
  SET/GRAPH XAXIS='XLOW','XUP',1,0.083333333333
! Set location text left.
  COMP/KEY XLOW = 'XLOW'+0.166666666667
! Create the reference image midtemp.bdf.
  STAT/TAB literature :Year
  WRITE/KEY QQR/R/1/1 0.
  COMP/KEY QQR = ('OUTPUTR(2)'-'OUTPUTR(1)')/5000
  CREATE/IMA midtemp 1,5000 'OUTPUTR(1)','QQR' NODATA
  COMP midtemp = 0

! Computations Figures 1-3.
  WRITE/KEY LABEL/C/1/21 0
  WRITE/DESCR midtemp.tbl LABEL0001/C/1/3 ALL
  WRITE/DESCR midtemp.tbl LABEL0002/C/1/3 CFS
  WRITE/DESCR midtemp.tbl LABEL0003/C/1/3 FMS
  WRITE/KEY QQI/I/1/1 0.
  WRITE/KEY LOOP1/I/1/1 0.
  WRITE/KEY AX0/I/1/1 0.
! The 3 fits.
  DO LOOP1 = 1 3 1
  COMP/KEY AX0 = 'AX0'+1
  WRITE/KEY TABLE/C/1/18 literature
  WRITE/KEY X/C/1/18 YEAR
  WRITE/KEY Y/C/1/18 QQQQ'AX0'
! Create the reference image QQ.bdf.
  CREATE/IMA QQ 1,5000 1995,.01
  COMP QQQ = QQ
  COPY/IT QQ QQ
  COMP/TAB QQ :X = 1995+.01*(SEQ-1)
  CONVERT/TAB QQ = QQ :X :X QQQ SPLINE
! Create the fitting file QQ.fit.
  CREATE/IMA  QQ.fit 1,1 1,1 NODATA
  WRITE/DESCR QQ.fit QQ1/C/1/200 "POLY(X;A0,A1)A0=1. A1=0."
  COPY/DD QQ.fit QQ1/C/1/200 QQ.fit FIT0001/C/1/200
  WRITE/DESCR QQ.fit FITCHAR/C/1/15 "N5          BDF"
  WRITE/DESCR QQ.fit FITINTG/I/1/1 1.
  WRITE/DESCR QQ.fit FITREAL/R/1/1 1.
  WRITE/DESCR QQ.fit FITERROR/D/1/1 1.
  WRITE/DESCR QQ.fit FITPARAM/D/1/1 1.
! Compute the fit FITPOLY1.tbl.
  $cp 'TABLE'.tbl QQ.tbl
  SORT/TAB QQ :'X'
! PRINT=5: show impressions every 5 iterations.
  SET/FIT FUNCT=QQ METHOD=NR PRINT=5
  SHOW/FIT QQ
! (Maximal function evaluations = 10000),(precission) QQ.tbl ('Y'-column:
! the dependent variable), ('X'-column: the independent varable) QQ.fit.
  FIT/TABLE 40000,1.E-07 QQ :'Y', :'X' QQ
! Save and rearrange the fitting parameters in QQ.tbl.
  CREATE/IMAGE QQ0 1,1 1,1
  COPY/IT QQ0 QQ
  SAVE/FIT QQ @1 QQ
  DEL/COL QQ #1
  COPY/TAB QQ FITPOLY1
  DEL/DESCR FITPOLY1.tbl HISTORY
! Compute the fit FITPOLY1.bdf.
  COMP FITPOLY1 = 0.*QQ
  WRITE/KEY POLYI/I/1/3 1
! Fit a polynome.
  WRITE/KEY LOOP2/I/1/1 0.
  WRITE/KEY AX1/I/1/1 0.
  WRITE/KEY AX2/R/1/1 0.
  DO LOOP2 = 1 2 1
  COMP/KEY AX1 = 1000*'AX1'
  WRITE/KEY AX3/C/1/1 'AX1'
  WRITE/KEY A'AX3'/R/1/1 0.
  COPY/TK FITPOLY1.tbl :A'AX3' @1 A'AX3'
  NAME/COL FITPOLY1 :A'AX3' E12.6
  NAME/COL FITPOLY1 :A'AX3'_ERROR E12.6
  COPY/KK A'AX3' AX2
  COMP FITPOLY1 = FITPOLY1+('AX2'*(QQ**'AX3'))
  COMP/KEY AX1 = ('AX1'/1000)+1
  ENDDO
! Compute the data images.
  CONVERT/TAB midtemp'AX0' = literature :Year :QQQQ'AX0' midtemp SPLINE
  COMP FITQQQQ'AX0' = FITPOLY1
! Write the slopes.
  COPY/KD A0 midtemp.tbl QQQQ'AX0'_A0/R/1/1  
  COPY/KD A1 midtemp.tbl QQQQ'AX0'_A1/R/1/1  
  IF A1 .GE. 0 THEN
  WRITE/KEY QQSIGN/C/1/1 "+"
  ELSE
  WRITE/KEY QQSIGN/C/1/1 "-"
  ENDIF
  COMP/KEY QQR = M$ABS(M$LOG10(M$ABS('A1')))+1.
  COMP/KEY A1 = M$ABS(100.*'A1')
  WRITE/KEY QQSLOPE/C/1/4 'A1'
  WRITE/KEY QQEXP/C/1/1 'QQR'
  COPY/DK midtemp.tbl LABEL'AX0' LABEL/C/1/21
  WRITE/KEY I/I/1/1 60
  STAT/TAB literature :I'AX0'
  COMP/KEY I = 60*'OUTPUTR(3)'
  COPY/KD I midtemp.tbl NUMBER'AX0'/I/1/1  
! Compute the percentages.
  COPY/DK FITPOLY1 START QQR
  COMP/KEY QQR = 10000.*'QQR'
  COPY/KD QQR FITPOLY1 START
  COPY/DK FITPOLY1 STEP QQR
  COMP/KEY QQR = 10000.*'QQR'
  COPY/KD QQR FITPOLY1 STEP
  COMP/KEY QQI = 10000.*'XUP'
  READ/IMA FITPOLY1 'QQI',1
  WRITE/KEY PER1/R/1/1 'OUTPUTR(1)'
  COMP/KEY QQI = 10000.*'XLOW'
  READ/IMA FITPOLY1 'QQI',1
  WRITE/KEY PER2/R/1/1 'OUTPUTR(1)'
  COMP/KEY PER1 = 100*(PER1-PER2)/PER2
  COPY/KD PER1 midtemp.tbl PERCENT'AX0'/R/1/1  
! Write the percentages.
  COMP/KEY QQI = M$ABS('PER1')
  WRITE/KEY PER/I/1/1 'QQI'
! Write the labels.
  WRITE/KEY FIG1'AX0'/C/1/31 'LABEL':no='I',s='QQSIGN''QQSLOPE'E-'QQEXP',p='QQSIGN''PER'
  WRITE/KEY FIG2'AX0'/C/1/31 'LABEL':no='I'
  WRITE/KEY FIG3'AX0'/C/1/31 'LABEL':p='QQSIGN''PER'
  ENDDO
! Write the results to literature.tbl.
  COPY/DD midtemp.tbl QQQQ0001_A0/R/1/1 literature.tbl ALL_INTER/R/1/1  
  COPY/DD midtemp.tbl NUMBER0001/I/1/1  literature.tbl ALL_NUMBER/I/1/1
  COPY/DD midtemp.tbl QQQQ0001_A1/R/1/1 literature.tbl ALL_SLOPE/R/1/1  
  COPY/DD midtemp.tbl PERCENT0001/R/1/1 literature.tbl ALL_%/R/1/1
  COPY/DD midtemp.tbl QQQQ0002_A0/R/1/1 literature.tbl CFS_INTER/R/1/1  
  COPY/DD midtemp.tbl NUMBER0002/I/1/1  literature.tbl CFS_NUMBER/I/1/1
  COPY/DD midtemp.tbl QQQQ0002_A1/R/1/1 literature.tbl CFS_SLOPE/R/1/1  
  COPY/DD midtemp.tbl PERCENT0002/R/1/1 literature.tbl CFS_%/R/1/1
  COPY/DD midtemp.tbl QQQQ0003_A0/R/1/1 literature.tbl FMS_INTER/R/1/1  
  COPY/DD midtemp.tbl NUMBER0003/I/1/1  literature.tbl FMS_NUMBER/I/1/1
  COPY/DD midtemp.tbl QQQQ0003_A1/R/1/1 literature.tbl FMS_SLOPE/R/1/1  
  COPY/DD midtemp.tbl PERCENT0003/R/1/1 literature.tbl FMS_%/R/1/1
  COPY/DK midtemp.tbl NUMBER0001/I/1/1  QQI/I/1/5
  COPY/KT QQI/I/1/5 literature.tbl :SUMALL @60
  COPY/DK midtemp.tbl NUMBER0002/I/1/1  QQI/I/1/5
  COPY/KT QQI/I/1/5 literature.tbl :SUMCFS @60
  COPY/DK midtemp.tbl NUMBER0003/I/1/1  QQI/I/1/5
  COPY/KT QQI/I/1/5 literature.tbl :SUMFMS @60
  COPY/DK midtemp.tbl PERCENT0001/R/1/1 QQR
  COPY/KT QQR literature.tbl :PROALL @60
  COPY/DK midtemp.tbl PERCENT0002/R/1/1 QQR
  COPY/KT QQR literature.tbl :PROCFS @60
  COPY/DK midtemp.tbl PERCENT0003/R/1/1 QQR
  COPY/KT QQR literature.tbl :PROFMS @60
! Integer.
  COMP/TAB literature :PROALL = (:PROALL/(ABS(:PROALL)+1.E-19))*(INT(ABS(:PROALL)-.5))
  COMP/TAB literature :PROCFS = (:PROCFS/(ABS(:PROCFS)+1.E-19))*(INT(ABS(:PROCFS)-.5))
  COMP/TAB literature :PROFMS = (:PROFMS/(ABS(:PROFMS)+1.E-19))*(INT(ABS(:PROFMS)-.5))

! Fits Figure 1.
  $mv midtemp0001.bdf midtemp10001.bdf
  $mv midtemp0002.bdf midtemp10002.bdf
  $mv midtemp0003.bdf midtemp10003.bdf
  $mv FITQQQQ0001.bdf fittemp10001.bdf
  $mv FITQQQQ0002.bdf fittemp10002.bdf
  $mv FITQQQQ0003.bdf fittemp10003.bdf

! Plot Figure 1
  SET/GRAPH YAXIS=0,2.5,.5,.1
  ASSIGN/GRAPHICS POSTSCRIPT
  WRITE/KEY LOOP/I/1/1 0
  DO LOOP = 1 2 1
! Plot axes and coordinates.
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=8 LTYPE=3 COLOUR=1 ! black text on white background
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=5 LTYPE=3 COLOUR=1 ! black text on yellow background
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=0 LTYPE=3 COLOUR=1 ! black text on yellow background
  COMP/TAB literature :QQ = :QQQQ0001
  COMP/TAB literature :Papers = :Year
  NAME/COL literature :Papers F4.2 "number/day"
  PLOT/TAB literature :Year :Papers
  COMP/TAB literature :Papers = :QQ
  DEL/COL literature :QQ
  LABEL/GRAPHICS "Five-year period analysis:" 'XLOW',2.4 0 1 1
  LABEL/GRAPHICS "number/5years, slope [papers/day/year], and progress [%/5year]" 'XLOW',2.3 0 1 1
! All papers (red, filled squares & dashed lines).
  SET/GRAPH STYPE=21 LTYPE=3 COLOUR=2
  OVERPLOT/TAB literature :Year :Papers
  OVERPLOT midtemp10001
  OVERPLOT fittemp10001
  LABEL/GRAPHICS 'FIG10001' 'XLOW',2.2 0 1 1
! CFS/ME papers (green, filled triangles & solid lines).
  SET/GRAPH STYPE=20 LTYPE=1 COLOUR=6
  OVERPLOT/TAB literature :Year :QQQQ0002
  OVERPLOT midtemp10002
  OVERPLOT fittemp10002
  LABEL/GRAPHICS 'FIG10002' 'XLOW',2.1 0 1 1
! FMS papers (blue, asterisks & dash-dotted lines).
  SET/GRAPH STYPE=7 LTYPE=4 COLOUR=4
  OVERPLOT/TAB literature :Year :QQQQ0003
  OVERPLOT midtemp10003
  OVERPLOT fittemp10003
  LABEL/GRAPHICS 'FIG10003' 'XLOW',2.0 0 1 1
  ASSIGN/GRAPHICS G,0
  ENDDO

! Create Figure 1.
! $convert -rotate 90 -crop 730x585+35-50 postscript.ps literature1.jpg
  $convert -rotate 90 -crop 730x585+35-50 postscript.ps postscript.gif
  $giftrans -g "#ffffff"="#F3E5F1" postscript.gif > literature1.jpg
! $convert -rotate 90 -crop 730x585+35-50 postscript.ps literature1.ps
! $ps2pdf literature1.ps literature1.pdf
! $mv postscript.ps literature1.ps

! Fits Figure 2.
  CONVERT/TAB midtemp20001 = literature :Year :SUMALL midtemp SPLINE
  CONVERT/TAB midtemp20002 = literature :Year :SUMCFS midtemp SPLINE
  CONVERT/TAB midtemp20003 = literature :Year :SUMFMS midtemp SPLINE

! Plot Figure 2.
  SET/GRAPH YAXIS=500,2400,500,100
  COMP/TAB literature :Papers = -1
  NAME/COL literature :Papers F4.0 "number/5year"
  ASSIGN/GRAPHICS POSTSCRIPT
  WRITE/KEY LOOP/I/1/1 0
  DO LOOP = 1 2 1
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=8 LTYPE=3 COLOUR=1 ! black text on white background
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=5 LTYPE=3 COLOUR=1 ! black text on yellow background
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=0 LTYPE=3 COLOUR=1 ! black text on yellow background
  PLOT/TAB literature :Year :Papers
  LABEL/GRAPHICS "Five-year period analysis: absolute number" 'XLOW',2000 0 1 1
  LABEL/GRAPHICS "This month:" 'XLOW',1920 0 1 1
! All papers (red, filled squares & dashed lines).
  SET/GRAPH STYPE=21 LTYPE=3 COLOUR=2
  OVERPLOT/TAB literature :Year :SUMALL
  OVERPLOT midtemp20001
  LABEL/GRAPHICS 'FIG20001' 'XLOW',1840 0 1 1
! CFS/ME papers (green, filled triangles & solid lines).
  SET/GRAPH STYPE=20 LTYPE=1 COLOUR=6
  OVERPLOT/TAB literature :Year :SUMCFS
  OVERPLOT midtemp20002
  LABEL/GRAPHICS 'FIG20002' 'XLOW',1760 0 1 1
! FMS papers (blue, asterisks & dash-dotted lines).
  SET/GRAPH STYPE=7 LTYPE=4 COLOUR=4
  OVERPLOT/TAB literature :Year :SUMFMS
  OVERPLOT midtemp20003
  LABEL/GRAPHICS 'FIG20003' 'XLOW',1680 0 1 1
  ASSIGN/GRAPHICS G,0
  ENDDO

! Create Figure 2.
! $convert -rotate 90 -crop 730x585+35-50 postscript.ps literature2.jpg
  $convert -rotate 90 -crop 730x585+35-50 postscript.ps postscript.gif
  $giftrans -g "#ffffff"="#F3E5F1" postscript.gif > literature2.jpg
! $convert -rotate 90 -crop 730x585+35-50 postscript.ps literature2.ps
! $ps2pdf literature2.ps literature2.pdf
! $mv postscript.ps literature2.ps

! Fits Figure 3.
  CONVERT/TAB midtemp30001 = literature :Year :PROALL midtemp SPLINE
  CONVERT/TAB midtemp30002 = literature :Year :PROCFS midtemp SPLINE
  CONVERT/TAB midtemp30003 = literature :Year :PROFMS midtemp SPLINE

! Plot Figure 3.
  SET/GRAPH YAXIS=-44,70,10,2
  COMP/TAB literature :Progress = -1000
  NAME/COL literature :Progress F4.0 "%/5year"
  ASSIGN/GRAPHICS POSTSCRIPT
  WRITE/KEY LOOP/I/1/1 0
  DO LOOP = 1 2 1
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=8 LTYPE=3 COLOUR=1 ! black text on white background
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=5 LTYPE=3 COLOUR=1 ! black text on yellow background
  SET/GRAPH PMODE=1 STYPE=21 BCOLOUR=0 LTYPE=3 COLOUR=1 ! black text on yellow background
  PLOT/TAB literature :Year :Progress
  OVERPLOT midtemp
  LABEL/GRAPHICS "Five-year period analysis: relative number" 'XLOW',35 0 1 1
  LABEL/GRAPHICS "This month:" 'XLOW',30.84 0 1 1
  LABEL/GRAPHICS "Increasing" 'XLOW',3.32 0 1 1
  LABEL/GRAPHICS "Decreasing" 'XLOW',-3.00 0 1 1
! All papers (red, filled squares & dashed lines).
  SET/GRAPH STYPE=21 LTYPE=3 COLOUR=2
  OVERPLOT/TAB literature :Year :PROALL
  OVERPLOT midtemp30001
  LABEL/GRAPHICS 'FIG30001' 'XLOW',26.68 0 1 1
! CFS/ME papers (green, filled triangles & solid lines).
  SET/GRAPH STYPE=20 LTYPE=1 COLOUR=6
  OVERPLOT/TAB literature :Year :PROCFS
  OVERPLOT midtemp30002
  LABEL/GRAPHICS 'FIG30002' 'XLOW',22.52 0 1 1
! FMS papers (blue, asterisks & dash-dotted lines).
  SET/GRAPH STYPE=7 LTYPE=4 COLOUR=4
  OVERPLOT/TAB literature :Year :PROFMS
  OVERPLOT midtemp30003
  LABEL/GRAPHICS 'FIG30003' 'XLOW',18.36 0 1 1
  ASSIGN/GRAPHICS G,0
  ENDDO

! Create Figure 3.
! $convert -rotate 90 -crop 730x585+35-50 postscript.ps literature3.jpg
  $convert -rotate 90 -crop 730x585+35-50 postscript.ps postscript.gif
  $giftrans -g "#ffffff"="#F3E5F1" postscript.gif > literature3.jpg
! $convert -rotate 90 -crop 730x585+35-50 postscript.ps literature3.ps
! $ps2pdf literature3.ps literature3.pdf
! $mv postscript.ps literature3.ps

! Create output files.
  NAME/COL literature :QQQQ0001 :ALL
  NAME/COL literature :QQQQ0002 :CFS
  NAME/COL literature :QQQQ0003 :FMS
  DEL/COL literature :I0001
  DEL/COL literature :I0002
  DEL/COL literature :I0003
  NAME/COL literature :Year     :QQ
  NAME/COL literature :QQ       :YEAR
  DEL/COL literature :Papers
  DEL/COL literature :Progress
  ASSIGN/PRINT FILE literature.txt
  PRINT/TAB literature
  ASSIGN/PRINT TERMINAL
  COPY/TAB literature midtemp
  COPY/TAB midtemp literature
  DEL/DESCR literature.tbl HISTORY

! Show the output files and Figures.
  READ/TAB literature
  READ/DESCR literature.tbl *
  $xv literature1.jpg &
  $xv literature2.jpg &
  $xv literature3.jpg &
! $gv -landscape literature1.ps &
! $gv -landscape literature2.ps &
! $gv -landscape literature3.ps &
! $acroread literature1.pdf &
! $acroread literature2.pdf &
! $acroread literature3.pdf &

! Update directory.
  $rm FITPOLY1.*
  $rm fittemp1000*.bdf
  $rm QQ*.*
  $rm postscript.*
! $rm literature*.ps
  $rm *.plt
  DEL/TEMP

! Logout
  ECHO/OFF
  BYE